mirror of
https://github.com/ggerganov/llama.cpp.git
synced 2024-11-11 13:30:35 +00:00
f3f65429c4
* scripts : update sync [no ci] * files : relocate [no ci] * ci : disable kompute build [no ci] * cmake : fixes [no ci] * server : fix mingw build ggml-ci * cmake : minor [no ci] * cmake : link math library [no ci] * cmake : build normal ggml library (not object library) [no ci] * cmake : fix kompute build ggml-ci * make,cmake : fix LLAMA_CUDA + replace GGML_CDEF_PRIVATE ggml-ci * move public backend headers to the public include directory (#8122) * move public backend headers to the public include directory * nix test * spm : fix metal header --------- Co-authored-by: Georgi Gerganov <ggerganov@gmail.com> * scripts : fix sync paths [no ci] * scripts : sync ggml-blas.h [no ci] --------- Co-authored-by: slaren <slarengh@gmail.com>
59 lines
1.6 KiB
CMake
59 lines
1.6 KiB
CMake
set(BUILD_NUMBER 0)
|
|
set(BUILD_COMMIT "unknown")
|
|
set(BUILD_COMPILER "unknown")
|
|
set(BUILD_TARGET "unknown")
|
|
|
|
# Look for git
|
|
find_package(Git)
|
|
if(NOT Git_FOUND)
|
|
find_program(GIT_EXECUTABLE NAMES git git.exe)
|
|
if(GIT_EXECUTABLE)
|
|
set(Git_FOUND TRUE)
|
|
message(STATUS "Found Git: ${GIT_EXECUTABLE}")
|
|
else()
|
|
message(WARNING "Git not found. Build info will not be accurate.")
|
|
endif()
|
|
endif()
|
|
|
|
# Get the commit count and hash
|
|
if(Git_FOUND)
|
|
execute_process(
|
|
COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
OUTPUT_VARIABLE HEAD
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
RESULT_VARIABLE RES
|
|
)
|
|
if (RES EQUAL 0)
|
|
set(BUILD_COMMIT ${HEAD})
|
|
endif()
|
|
execute_process(
|
|
COMMAND ${GIT_EXECUTABLE} rev-list --count HEAD
|
|
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
|
OUTPUT_VARIABLE COUNT
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
RESULT_VARIABLE RES
|
|
)
|
|
if (RES EQUAL 0)
|
|
set(BUILD_NUMBER ${COUNT})
|
|
endif()
|
|
endif()
|
|
|
|
if(MSVC)
|
|
set(BUILD_COMPILER "${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION}")
|
|
set(BUILD_TARGET ${CMAKE_VS_PLATFORM_NAME})
|
|
else()
|
|
execute_process(
|
|
COMMAND sh -c "$@ --version | head -1" _ ${CMAKE_C_COMPILER}
|
|
OUTPUT_VARIABLE OUT
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
)
|
|
set(BUILD_COMPILER ${OUT})
|
|
execute_process(
|
|
COMMAND ${CMAKE_C_COMPILER} -dumpmachine
|
|
OUTPUT_VARIABLE OUT
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
)
|
|
set(BUILD_TARGET ${OUT})
|
|
endif()
|